***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 26, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PDZ20B-AU A K
.param
+vc0 = 3.396e-10	 vc1 = 9.285e-11   	 vc2 = 7.362e-1		 vc3 = 1.394e-10	  vc4 = 7.590e-2
+tc1 = 2.451e-2		 tc2 = 1.037e-2		 tc3 = 2.281e-2		 tc4 = 2.017e-2 
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1.137e-14	   n = 1.122e0		  rs = 1.082e-1		ikf = 8.314e-2
+ibv = 50e-6		 nbv = 1		  bv = 20
***** capacitance parameter *****
+cjo = 2.201e-11	   m = 3.348e-1		  vj = 6.244e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.147		 xti = 3
+trs1 = 7.542e-4	trs2 = 5.821e-6		tikf = 3.5e-3
+tbv1 = 7.836e-4	tbv2 = -1.145e-7
.ends PDZ20B-AU
*$
